/**********************************************************************
* File: F2812_nonBIOS_ram.cmd -- Linker command file for non-DSP/BIOS
* code with DSP in jump-to-H0SARAM boot mode.
* History:
*   01/20/11 - Deleted unneeded Boot ROM memory definitions (D. Alter)
*   02/14/05 - made consistent with DSP/BIOS linkage allocation (D. Alter)
*   09/08/03 - original (based on DSP28 header files v1.00, D. Alter)
**********************************************************************/

MEMORY
{
PAGE 0:    /* Program Memory */
   L0SARAM          : origin = 0x008000, length = 0x001000     /* L0 SARAM */
   ZONE6            : origin = 0x100000, length = 0x010000     /* XINTF Zone 6 - 64Kw SRAM on eZdspF2812 */
   OTP              : origin = 0x3D7800, length = 0x000400     /* OTP */
   FLASH_ABCDEFGHIJ : origin = 0x3D8000, length = 0x01FF80     /* FLASH, All sectors combined */
   CSM_RSVD         : origin = 0x3F7F80, length = 0x000076     /* Part of FLASH sector A.  Reserved when CSM is in use. */
   BEGIN_FLASH      : origin = 0x3F7FF6, length = 0x000002     /* Part of FLASH sector A.  Used for "boot to flash" bootloader mode. */
   PASSWORDS        : origin = 0x3F7FF8, length = 0x000008     /* Part of FLASH sector A.  CSM password locations. */
   BEGIN_H0         : origin = 0x3F8000, length = 0x000002     /* Part of H0SARAM.  Used for "boot to H0" bootloader mode. */
   H0SARAM          : origin = 0x3F8002, length = 0x001FFE     /* H0 SARAM */
   IQTABLES         : origin = 0x3FF000, length = 0x000B50     /* Part of Boot ROM */
   RESET            : origin = 0x3FFFC0, length = 0x000002     /* part of boot ROM (MP/MCn=0) or XINTF zone 7 (MP/MCn=1) */

 PAGE 1 :   /* Data Memory */
   M0SARAM          : origin = 0x000000, length = 0x000400     /* M0 SARAM */
   M1SARAM          : origin = 0x000400, length = 0x000400     /* M1 SARAM */
   L1SARAM          : origin = 0x009000, length = 0x001000     /* L1 SARAM */
}

 
SECTIONS
{
/*** Compiler Required Sections ***/

  /* Program memory (PAGE 0) sections */
   .text             : > H0SARAM,        PAGE = 0
   .cinit            : > H0SARAM,        PAGE = 0
   .const            : > L0SARAM,        PAGE = 0
   .econst           : > L0SARAM,        PAGE = 0      
   .pinit            : > H0SARAM,        PAGE = 0
   .reset            : > RESET,          PAGE = 0, TYPE = DSECT  /* We are not using the .reset section */
   .switch           : > H0SARAM,        PAGE = 0

  /* Data Memory (PAGE 1) sections */
   .bss              : > L1SARAM,        PAGE = 1
   .ebss             : > L1SARAM,        PAGE = 1
   .cio              : > L1SARAM,        PAGE = 1
   .stack            : > M1SARAM,        PAGE = 1
   .sysmem           : > L1SARAM,        PAGE = 1
   .esysmem          : > L1SARAM,        PAGE = 1

/*** User Defined Sections ***/
   codestart         : > BEGIN_H0,       PAGE = 0                /* Used by file CodeStartBranch.asm */
   internalMemFuncs  : > H0SARAM,        PAGE = 0                /* Used by file Xintf.c.  Link to internal memory. */
}

/******************* end of file ************************/
