* [Disclaimer] (C) Copyright Texas Instruments Incorporated 1999 All rights reserved
* Texas Instruments Incorporated hereby grants the user of this SPICE Macro-model a
* non-exclusive, nontransferable license to use this SPICE Macro-model under the following
* terms. Before using this SPICE Macro-model, the user should read this license. If the
* user does not accept these terms, the SPICE Macro-model should be returned to Texas
* Instruments within 30 days. The user is granted this license only to use the SPICE
* Macro-model and is not granted rights to sell, load, rent, lease or license the SPICE
* Macro-model in whole or in part, or in modified form to anyone other than user. User may
* modify the SPICE Macro-model to suit its specific applications but rights to derivative
* works and such modifications shall belong to Texas Instruments. This SPICE Macro-model is
* provided on an "AS IS" basis and Texas Instruments makes absolutely no warranty with
* respect to the information contained herein. TEXAS INSTRUMENTS DISCLAIMS AND CUSTOMER
* WAIVES ALL WARRANTIES, EXPRESS OR IMPLIED, INCLUDING WARRANTIES OF MERCHANTABILITY OR
* FITNESS FOR A PARTICULAR PURPOSE. The entire risk as to quality and performance is with
* the Customer. ACCORDINGLY, IN NO EVENT SHALL THE COMPANY BE LIABLE FOR ANY DAMAGES,
* WHETHER IN CONTRACT OR TORT,INCLUDING ANY LOST PROFITS OR OTHER INCIDENTAL, CONSEQUENTIAL,
* EXEMPLARY, OR PUNITIVE DAMAGES ARISING OUT OF THE USE OR APPLICATION OF THE SPICE
* Macro-model provided in this package. Further, Texas Instruments reserves the right to
* discontinue or make changes without notice to any product herein to improve reliability,
* function, or design. Texas Instruments does not convey any license under patent rights or
* any other intellectual property rights, including those of third parties.
*
* THS4082 SUBCIRCUIT
* HIGH SPEED MONLITHIC OPERATIONAL AMPLIFIER
* WRITTEN 4/10/00
* Revised 8/10/01 to use resistor sense for dynamic bias circuit
* Took the "B" off the end of the subckt, it would be confusing for dual
*   device - Bruce Carter 1-14-2003
* TEMPLATE=X^@REFDES %IN+ %IN- %VCC+ %VCC- %OUT @MODEL
* CONNECTIONS:      NON-INVERTING INPUT
*                   | INVERTING INPUT
*                   | | POSITIVE POWER SUPPLY
*                   | | | NEGATIVE POWER SUPPLY
*                   | | | | OUTPUT
*                   | | | | |
*                   | | | | |
*                   | | | | |
.SUBCKT THS4082     1 2 3 4 5
*
* INPUT *
Q1         33 1 06 NPN_IN 1
Q2         34 2 07 NPN_IN 1
R1         17 06  600
R2         17 07  600

* PROTECTION DIODES *
D2         5 3 D1N
D1         4 5 D1N
D4         4 2 D1N
D6         4 1 D1N
D5         1 3 D1N
D8         22 1 D1N
D7         22 2 D1N
D3         2 3 D1N

* SECOND STAGE *
Q3         08 Vref 33 PNP 0.5
Q6         10 08 09 NPN 0.5
Q4         10 Vref 34 PNP 0.5
Q5         08 09 11 NPN 1
Q7         09 09 12 NPN 1
Cc         0 10  Ct 2.35p
R3         4 11  500
R4         4 12  500

* HIGH FREQUENCY SHAPING *
Lhf         18 19  9.4n
Rhf         13 19  25
Chf         0  13  30p
Ehf         18 0 10 0 1

* OUTPUT *
Q8         113 13 35 PNP 1.5
Rs1        113 4 Rt 750
Ef1        115 0 113 4 1
EIr1       119 0 117 115 1
VIr1       117 0 DC 0.16
G3           3 35 119 0 1

Q9         114 13 14 NPN 1.5
Rs2        114 3 Rt 750
Ef2        116 0 3 114 1
EIr2       120 0 116 118 1
VIr2       118 0 DC 0.15
G5          14 4 120 0 1

Q10         3 35 15 NPN 12
Q11         4 14 16 PNP 12
R5         20 15  4
R7         16 20  4

* COMPLEX OUTPUT IMPEDANCE *
R8         32 20  10
R9         31 20  3
L1         31 5  10n
C1         32 5  20p

* BIAS SOURCES *
G1         3 33 3 4 15e-6
G2         3 34 3 4 15e-6
G4         17 4 3 4 15e-6
I1         3 33  DC 0.33e-3
I2         3 34  DC 0.33e-3
I4         17 4  DC 0.43e-3
V1         3 Vref DC 1.85

* MODELS *
.MODEL NPN_IN NPN
+ IS=170E-18 BF=400 NF=1 VAF=100 IKF=0.0389 ISE=7.6E-18
+ NE=1.13489 BR=1.11868 NR=1 VAR=4.46837 IKR=8 ISC=8E-15
+ NC=1.8 RB=25 RE=0.1220 RC=20 CJE=120.2E-15 VJE=1.0888 MJE=0.381406
+ VJC=0.589703 MJC=0.265838 FC=0.1 CJC=133.8E-15 XTF=272.204 TF=12.13E-12
+ VTF=10 ITF=0.147 TR=3E-09 XTB=1 XTI=5 KF=1.5E-14

.MODEL NPN NPN
+ IS=170E-18 BF=100 NF=1 VAF=100 IKF=0.0389 ISE=7.6E-18
+ NE=1.13489 BR=1.11868 NR=1 VAR=4.46837 IKR=8 ISC=8E-15
+ NC=1.8 RB=250 RE=0.1220 RC=200 CJE=120.2E-15 VJE=1.0888 MJE=0.381406
+ VJC=0.589703 MJC=0.265838 FC=0.1 CJC=133.8E-15 XTF=272.204 TF=12.13E-12
+ VTF=10 ITF=0.147 TR=3E-09 XTB=1 XTI=5

.MODEL PNP PNP
+ IS=296E-18 BF=100 NF=1 VAF=100 IKF=0.021 ISE=494E-18
+ NE=1.49168 BR=0.491925 NR=1 VAR=2.35634 IKR=8 ISC=8E-15
+ NC=1.8 RB=250 RE=0.1220 RC=200 CJE=120.2E-15 VJE=0.940007 MJE=0.55
+ VJC=0.588526 MJC=0.55 FC=0.1 CJC=133.8E-15 XTF=141.135 TF=12.13E-12
+ VTF=6.82756 ITF=0.267 TR=3E-09 XTB=1 XTI=5

.MODEL Rt RES TC1=0.004

.MODEL Ct CAP TC1=-0.0025

.MODEL D1N D IS=10E-15 N=1.836 ISR=1.565e-9 IKF=.04417 BV=30 IBV=10E-6 RS=45
+ TT=11.54E-9 CJO=1E-12 VJ=.5 M=.3333

.ENDS

