**                                                                           
** Property of Texas Instruments -- For Unrestricted Internal Use Only --    
** Unauthorized reproduction and/or distribution is strictly prohibited.     
** This product is protected under copyright law and trade secret law as     
** an unpublished work.  Created 1997, (C) Copyright 1997, 1998, 1999 Texas 
** Instruments.  All rights reserved.
**                                                                           
** These commodities are under U.S. Government distribution license          
** control. As such, they are not to be re-exported without prior            
** approval of the U.S. Department of Commerce.                              
**                                                                           
***************************************************************************
*
*   Process:     1833C07.0, 1833A07.0 
*   Component:   RES_NPL_SIBLK
*   Description: SiBLK Poly Resistor  
*   Strength:    High
*   Model:       Passive Subcircuit
*   Source:      Process Control Document
*   SPICE:       HSPICE 97.4 or greater
*   Ownership:   TI SPICE Modeling Lab
*   Other:       
*
*   Model Version:   Final 2.00
*
***************************************************************************
* 
* Updates:
* 
* 10/26/98 - Final 1.01 - Corrected TC1 of body resistor model
* 03/19/99 - Final 2.00 - HSPICE version Final 2.00 models 
* 
***************************************************************************
*
*  Notices:
*      
*  1. TCs good from 25C to 125C.  Nominal temperature is 25C.
*  2. Each simulator requires its own file format.  Check to make sure the
*     "SPICE" line in the title block above matches your simulator.
*  3. Please do not alter any part of this file.  If you would like to make
*     a change, contact the TI SML staff.
*  4. All models created by the TI SML from PCD information.
*      
***************************************************************************
*
* Contents:
*
* Model Cards     
* RES_NPL_18C07        SiBLK Poly Resistor Body
* RES_NPL_HEAD_18C07   SiBLK Poly Resistor Head
*      
* Subcircuit Model
* R_NPL_18C07          SiBLK Poly Resistor
*
***************************************************************************
*
* Subcircuit:
*
*       Rhead   Rbody   Rhead
*     --/\/\/---/\/\/---/\/\/--
*             |       |       
*  Cpoly_sub ---     --- Cpoly_sub
*            ---     --- 
*             |_______|
*                 |
*
* Rhead=RSH_head/(W-WR)
* Rbody=RSH_body*(L-LR)/(W-WR)
* Cpoly_sub=CD_poly_sub*(L-LR)*(W-WR)/2
*
***************************************************************************
* Technology "Shrink"/Scaling factor
.param NPL_SCALE = 0.5

* Technology (PCD) Parameters

* Resistor body resistance (ohm/square)
.param RES_NPL_B = 124

* Resistor head resistivity (ohm-micron)
.param RES_NPL_H = 50

* Width reduction (microns)
.param RES_NPL_WR = 0.045

* Length reduction (microns)
.param RES_NPL_LR = 0.0

* Poly to substrate capacitance density (F/um^2)
.param CD_NPL_SUB = '1.1*6.91E-17'

* Poly resistor body temperature coefficients
.MODEL RES_NPL_18C07 R
+ SCALE = 1.107
+ TC1   = 1.65E-4
+ TC2   = 9.00E-7
+ TREF  = 25

* Poly resistor head temperature coefficients
.MODEL RES_NPL_HD_18C07 R
+ SCALE = 1.14
+ TC1   = 2.7E-4
+ TC2   = 3.25E-6
+ TREF  = 25
***************************************************************************
.SUBCKT  R_NPL_18C07  R0  R1  RT  W=0.0  L=0.0
RH1  R0  P1 RES_NPL_HD_18C07 'RES_NPL_H/((W*NPL_SCALE)-RES_NPL_WR)'  
RB   P1  P2 RES_NPL_18C07 'RES_NPL_B*(L*NPL_SCALE-RES_NPL_LR)/(W*NPL_SCALE-RES_NPL_WR)' 
RH2  P2  R1 RES_NPL_HD_18C07 'RES_NPL_H/(W*NPL_SCALE-RES_NPL_WR)'  
CT1  P1  RT  'CD_NPL_SUB*(W*NPL_SCALE-RES_NPL_WR) *(L*NPL_SCALE-RES_NPL_LR)/2'
CT2  P2  RT  'CD_NPL_SUB*(W*NPL_SCALE-RES_NPL_WR) *(L*NPL_SCALE-RES_NPL_LR)/2'
.ENDS R_NPL_18C07
***************************************************************************
