Design Simulations

Simulation Setup

The easiest way to analyze the noise performance of a circuit like this is to use a simulation program such as TINA.

The SPICE macros for the TL431 and LMP7704 included in the standard TINA library⁽¹⁾ do not include models for the noise performance, so separate voltage noise sources must be included in the simulation circuit (see Vn1 and Vn2 in the previous TINA schematic). The macros for the noise sources can be copied from the Vnoise.TSC file referred to in this E2E™ thread, and edited, and three parameters describing the noise characteristic of the devices entered (highlighted in bold in the following macro extract).

* BEGIN PROG NSE NANO VOLT/RT-HZ
.SUBCKT VNSE 1 2
* BEGIN SETUP OF NOISE GEN - NANOVOLT/RT-HZ
* INPUT THREE VARIABLES
* SET UP VNSE 1/F
* NV/RHZ AT 1/F FREQ
.PARAM NLF=225
* FREQ FOR 1/F VAL
.PARAM FLW=10
* SET UP VNSE FB
* NV/RHZ FLATBAND
.PARAM NVR=125
* END USER INPUT
* START CALC VALS
.PARAM GLF={PWR(FLW,0.25)*NLF/1164}
.PARAM RNV={1.184*PWR(NVR,2)}
.MODEL DVN D KF={PWR(FLW,0.5)/1E11}IS=1.0E-16
* END CALC VALS
I1 0 7 10E-3
I2 0 8 10E-3
D1 7 0 DVN
D2 8 0 DVN
E1 3 6 7 8 {GLF}
R1 3 0 1E9
R2 3 0 1E9
R3 3 6 1E9
E2 6 4 5 0 10
R4 5 0 {RNV}
R5 5 0 {RNV}
R6 3 4 1E9
R7 4 0 1E9
E3 1 2 3 4 1
C1 1 0 1E-15
C2 2 0 1E-15
C3 1 2 1E-15
.ENDS
* END PROG NSE NANOV/RT-HZ

NLF is the magnitude of the noise where the curve crosses the y-axis at the minimum frequency, and FLW is the frequency at which this happens. NVR is the magnitude of the wideband noise. These parameters can easily be taken from the data sheets of the devices (see the following figure). All values entered in the macros must be in nV/√Hz.